DevTrain - Feldprüfungen Serverseitig durchführen

Sie haben mindestens 2 Möglichkeiten, Formularfelder auf Fehlerhafte oder leere Eingaben zu prüfen. Clientseitig und Serverseitig. Im nachfolgenden Beispiel wird die Möglichkeit vorgestellt, Eingaben Serverseitig zu Prüfun und fehlerhafte Einträge auf der Site darzustellen.

<%
If Request.Form.Count > 0 Then
    FullName = Trim(Request.Form("FullName"))
    Email     = Trim(Request.Form("Email"))
    AgeGroup = Request.Form("AgeGroup")
    Gender    = Request.Form("Gender")

    '*** data validation
    If FullName = "" Then
        ErrorMsg = ErrorMsg & "Please enter your Full Name<br>"
    End If
    If Email = "" Then
        ErrorMsg = ErrorMsg & "Please enter your Email Address<br>"
    End If
    If AgeGroup = "" Then
        ErrorMsg = ErrorMsg & "Please enter your Age Group<br>"
    End If
    If Gender = "" Then
        ErrorMsg = ErrorMsg & "Please enter your Gender<br>"
    End If

    If ErrorMsg = "" Then
        Response.Redirect "default.asp"
    End If
End If
%>

<h1>Membership Registration</h1>

<%
If ErrorMsg <> "" Then %>
    <p><font color="#FF0000"><%= ErrorMsg %></font><p>
<% End If %>

<form action="<%= Request.ServerVariables("SCRIPT_NAME") %>" method=post>
Full Name<br>
<input type=text name=FullName value="<%= FullName %>">
<p>
Email<br>
<input type=text name=Email value="<%= Email %>">
<p>
<select name=AgeGroup>
    <option value="">Select your age
    <option value="under 18" <% If AgeGroup = "under 18" Then Response.Write "SELECTED" %>>under 18
    <option value="18 to 25" <% If AgeGroup = "18 to 25" Then Response.Write "SELECTED" %>>18 to 25
    <option value="25 to 35" <% If AgeGroup = "25 to 35" Then Response.Write "SELECTED" %>>25 to 35
    <option value="35 to 50" <% If AgeGroup = "35 to 50" Then Response.Write "SELECTED" %>>35 to 50
    <option value="over 50" <% If AgeGroup = "over 50" Then Response.Write "SELECTED" %>>over 50
</select>
<p>
<input type=radio name=Gender value=M <% If Gender = "M" Then Response.Write "CHECKED" %>> Male
<input type=radio name=Gender value=F <% If Gender = "F" Then Response.Write "CHECKED" %>> Female
<p>
<input type=submit value="Submit">
</form>

</font>